A layer around the deriving-aeson package, with the ability to strip one or more fields from the JSON output, and recover them when decoding using some specified defaults.

Examples

Setup

All the examples on this page are based on the following setup code:

>>> :set -XDataKinds
>>> :set -XDeriveGeneric
>>> :set -XDerivingVia
>>> :set -XGeneralizedNewtypeDeriving
>>> :set -XOverloadedStrings
>>> :set -XTypeApplications

>>> import Data.Aeson
>>> import Deriving.Aeson.Stripped
>>> import qualified Data.Set as Set
>>> import Data.Text (Text)

>>> :{
 newtype WrappedInt
     = WrappedInt Int
     deriving (FromJSON, Show, ToJSON)
:}

>>> :{
 data RecordTest = RecordTest
     { testBool     :: !Bool
     , testNumber   :: {-# UNPACK #-} !Int
     , testNewtype  :: !WrappedInt
     , testString   :: String
     , testIsString :: !Text
     , testList     :: ![Int]
     , testIsList   :: Set.Set Int
     , testMonoid   :: !Ordering
     , testValue    :: Double
     }
     deriving (Generic, Show)
     deriving (FromJSON, ToJSON)
         via StrippedJSON
             '[ RField "testBool"     'False
              , RField "testIsList"   (FromList '[ 13, 14, 13 ])
              , RField "testIsString" (FromString "text")
              , RField "testList"     '[ 10, 11, 12 ]
              , RField "testMonoid"   Mempty
              , RField "testNewtype"  (Coerce 42 Int)
              , RField "testNumber"   7
              , RField "testString"   "string"
              ]
             '[]
             RecordTest
:}

Note that the order of the RField instructions does not matter ..

>>> let recordTest = RecordTest True 1 (WrappedInt 2) "s" "t" [1..3] (Set.fromList [4..6]) GT 3.14

>>> :{
 data NonRecordTest
     = NonRecordTest () (Either String Int) (Maybe Int) ![Int] (Bool, Char, Int)
     deriving (Generic, Show)
     deriving (FromJSON, ToJSON)
         via StrippedJSON
             '[ CField 0 '()
              , CField 1 ('Left "test")
              , CField 3 (Pure 7)
              , CField 2 'Nothing
              , CField 4 '( 'False, "z", 42 )
              ]
             '[]
             NonRecordTest
:}

.. nor does the order of the CField instructions.

>>> let nonRecordTest = NonRecordTest () (Right 1) (Just 2) [3..5] (True, 'a', 6)

Stripping fields in a record value: ..

>>> encode recordTest
"{\"testValue\":3.14}"

.. and recovering them when decoding using the specified defaults:

>>> decode @RecordTest $ encode recordTest
Just (RecordTest {testBool = False, testNumber = 7, testNewtype = WrappedInt 42, testString = "string", testIsString = "text", testList = [10,11,12], testIsList = fromList [13,14], testMonoid = EQ, testValue = 3.14})

Stripping fields in a non-record value: ..

>>> encode nonRecordTest
"[]"

.. and recovering them when decoding using the specified defaults:

>>> decode @NonRecordTest $ encode nonRecordTest
Just (NonRecordTest () (Left "test") Nothing [7] (False,'z',42))

Specifying encoding / decoding options:

The second parameter to StrippedJSON works exactly the same as the only parameter to CustomJSON from the deriving-aeson package.

>>> encode $ StrippedJSON @'[] @'[ FieldLabelModifier CamelToSnake ] recordTest
"{\"test_bool\":true,\"test_number\":1,\"test_newtype\":2,\"test_string\":\"s\",\"test_is_string\":\"t\",\"test_list\":[1,2,3],\"test_is_list\":[4,5,6],\"test_monoid\":\"GT\",\"test_value\":3.14}"